ラベル VBA の投稿を表示しています。 すべての投稿を表示
ラベル VBA の投稿を表示しています。 すべての投稿を表示

2019年3月5日火曜日

VBA; 005 画像をセルのサイズに合わせて貼り付ける

自分用メモ。
画像を貼り付けるとき、セルに合わせてサイズ調整するのを手作業でやるのは面倒なのでその方法。
罫線を書いているときなど、セルぴったりにしてしまうと罫線よりも画像が上に描写されてしまうので、マージン有無の設定もできるように。

Private Sub pasteImageFromFile(targetRange As Range, imageFilePath As String, margin As Integer, isLink As Boolean)
    Dim image As Shape
    Dim zoom_scale As Double
    Dim margin_point As Double
    Dim ht As Integer
    Dim wd As Integer
    Dim isSave As Boolean
    
    margin_point = (margin * (72 / 25.4)) * 2
    
    If isLink = False Then
        isSave = True
    Else
        isSave = False
    End If

    Set image = targetRange.Worksheet.Shapes.AddPicture( _
        Filename:=imageFilePath, _
        LinkToFile:=isLink, _
        SaveWithDocument:=isSave, _
        Left:=targetRange.Left, Top:=targetRange.Top, _
        Width:=-1, Height:=-1)
    
    With image
        .LockAspectRatio = msoTrue
        ht = targetRange.Height - margin_point
        wd = targetRange.Width - margin_point
        If wd / .Width < ht / .Height Then
            zoom_scale = Application.WorksheetFunction.RoundDown(wd / .Width, 2)
        Else
            zoom_scale = Application.WorksheetFunction.RoundDown(ht / .Height, 2)
        End If
        
        .ScaleWidth zoom_scale, msoFalse, msoScaleFromTopLeft
        
        .Left = .Left + (targetRange.Width - .Width) / 2
        .Top = .Top + (targetRange.Height - .Height) / 2
    End With

End Sub

引数としては貼り付け先のrangeオブジェクト、イメージのファイルパス、マージン(mm)、リンクにするか貼り付けるか。
リンクにすると、ファイルにはリンク先の情報が保存されるので、ファイルサイズは小さくなるけど画像データを毎回読み込む必要あり。なのでexcelファイルだけでは配布できなくなる。
マージン(というより画像サイズ)は本来ポイント単位での指定だけど、いちいちmmに換算してられないので引数をmmで設定。上下左右のマージンなので、引数を2倍にして使う。
LockAspectRatioで縦横比を固定。
対象レンジの幅・高さとイメージのサイズから倍率を決定。このとき、縦横のどちらが大きいかを見て調整。最後にイメージの配置場所を、セルの中心に移動。

もともとどこかのサイトのコードを参考(というかほぼコピペ)で書いたんだけど、どこだったか探しても見つからなかったのでリンクが張れない。残念。

VBA; 004 行の高さをミリメートル単位で指定する

自分用メモ。
行の高さはポイント単位での指定なので、列の幅と違って素直に設定可能。

Private Sub setRowHeightByMillimeter(targetRange As Range, targetHeight As Integer)
    targetRange.RowHeight = Application.CentimetersToPoints(targetHeight / 10)
End Sub

VBA; 003 列の幅をミリメートル単位で指定する

自分用メモ。
excelでは列の幅指定はフォント依存。標準フォントで半角数字の'0'が何文字表示できるか、というわけのわからん単位なので、これをミリメートル単位で設定する方法。

列の幅はColumnWidthプロパティで設定する。前述のとおり、これがフォントに依存する単位なので、こいつを「ポイント」に変換する。1ポイントは0.35mm。
Widthプロパティはポイント単位の数値なので(統一しろや・・・)これを使う。

ColumnWidth / Width

で、1ポイントが文字単位に換算するといくつになるかがわかる。
ミリメートルをポイントに変換する必要もあるので、これはCentimetersToPointsメソッドを使う。名前の通り単位はセンチメートルなので、ミリメートルに変換するのを忘れない。

Private Sub setColumnWidthByMillimeter(targetRange As Range, targetWidth As Integer)
    Dim columnCount As Integer
    Dim i As Integer
    Dim j As Integer
    Dim col As Integer
    Dim objectWidth As Double
    
    columnCount = targetRange.Columns.Count - 1
    objectWidth = Application.CentimetersToPoints(targetWidth / 10)
    
    For i = 0 To 1
        For j = 0 To columnCount
            col = targetRange.Column + j
            With Columns(col)
                .ColumnWidth = objectWidth * (.ColumnWidth / .Width)
            End With
        Next
    Next
End Sub

ColumnWidthでは、複数列の幅を正しく取得できないっぽいので、指定したレンジの範囲で1列ごとに設定する。
また変換誤差が発生するのか、同じ処理をしても1回めと2回めとで結果が変わってしまうのでループで2回設定する。2回めで設定された幅は変わらない模様。

2019年3月3日日曜日

VBA; 002 テキストボックスの内容を変更する

自分用メモ。
マクロのフォームではなく、挿入→テキストボックスで入れたものの内容を変更する方法。

画像挿入で貼り付けた地図に番号を振って、あとでシャッフルするときなどに使用。

前準備として、テキストボックスの名前を連番にしておく。
ページレイアウト→配置→オブジェクトの選択と表示をクリックして、オブジェクトの一覧を表示。ここで名前を変更して、連番にする。
同じ名前も存在できるので、ユニークな情報ではなさそうだけど、とりあえず動くからこれ以上は調べない。


以下の例では0パディングしてない名前を前提にしているので、0パディングした場合はformat関数あたりを使って調整。
tbox_0 - tbox_19 まで20個のテキストボックスに、⑳ - ①までの丸数字(機種依存文字)を逆順に設定。
ちなみに21以降は文字コードが違うようで、いろいろ試したけどうまく振れなかったので今回は断念。
あと、テキストボックスの他、吹き出しを混ぜても問題なく動作した。


Option Explicit

Const HEADER_NAME = "tbox_"
Const MAX_NUM = 19

Private Sub setTboxesNumber()
    Dim i As Integer
    Dim box_name As String
    
    For i = 0 To MAX_NUM
        box_name = Trim(HEADER_NAME & Trim(str(i)))
        ActiveSheet.Shapes.Range(box_name).TextFrame.Characters.Text = Chr(Asc("⑳") - i)
    Next
End Sub

実行前実行後
しかしBASICだから当然なんだろうけど、for文が最後の数字までカウントされるの、cに慣れると気持ち悪いな。
ループカウンタを1から始めればMAX_NUMを20にできるんだけど、それはそれで0番目の要素が飛ばされるから気持ち悪い。

2019年3月2日土曜日

VBA; 001 オブジェクト変数または With ブロック変数が設定されていません

自分用メモ。
VBAは年に数回しか触らないので、以前調べたこともすぐ忘れちゃうからここにメモしよう。



実行時エラー '91':
オブジェクト変数または With ブロック変数が設定されていません。

と出たときは、大抵はオブジェクト変数に代入するときsetステートメントを忘れている。
integerとかstringとかはオブジェクト型じゃないので、そのまま代入可能。
でもrangeだとかworksheetだとかはオブジェクト型なので、setステートメントがないと代入不可。

    Dim i As Integer
    Dim rng As Range
    
    i = 0
    Set rng = Range("a:a")